Justin Bearden

IEE 574 – Summer 2012

Arizona State University

Case Study 1: Police Department Scheduling

# Introduction

Linear programming can be used to solve many interesting optimization problems. One interesting class of problems is personnel scheduling. These problems arise when a group needs to find how many workers to schedule to work for a set of time periods. The goal of linear programming in this situation is to attempt to optimize the number of workers based on some combination of criteria of cost or customer service.

This report investigates the scheduling of police officers for the Sacramento Police Department. The police department maintains a database of call data from its computer aided dispatch system. Each entry corresponds to one incident that an officer responded to. This data can be used to predict how many officers will be needed in coming weeks. Mathematical models representing the number of officers working each shift and the goal of the schedule can be created to define the new schedule. The goal will be to minimize the amount of surplus officers available to reduce cost and to minimize the total shortages of officers to increase customer service. Using the historical CAD data and the mathematical models a schedule is created for the police department.

# Modeling

The Sacramento police department maintains a database of call data from its computer aided dispatch system. The data for district 3 recorded in January 2012 was selected for this model. District 3 covers the Sacramento downtown area and the California State University campus where crime rate statistics for the year were shown to be higher than other districts. The number of calls for each hour of each day during the month ware summed and averages were calculated. These calculations were used to create a matrix of the average number of calls for each two hour period during a week (Monday to Sunday). The matrix was assigned to the variable D[j, k] and is represented by Table 1.

|  |  |  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- | --- | --- |
| **Average Calls** | **Day** | **Mon** | **Tue** | **Wed** | **Thu** | **Fri** | **Sat** | **Sun** |
| **Hour** | **T** | **1** | **2** | **3** | **4** | **5** | **6** | **7** |
| **0000-0200** | **1** | **14** | **8** | **9** | **14** | **17** | **25** | **33** |
| **0200-0400** | **2** | **8** | **6** | **8** | **8** | **10** | **14** | **21** |
| **0400-0600** | **3** | **5** | **3** | **4** | **4** | **4** | **6** | **6** |
| **0600-0800** | **4** | **14** | **13** | **14** | **13** | **14** | **9** | **8** |
| **0800-1000** | **5** | **14** | **21** | **26** | **18** | **20** | **17** | **15** |
| **1000-1200** | **6** | **19** | **23** | **31** | **21** | **23** | **19** | **16** |
| **1200-1400** | **7** | **21** | **25** | **30** | **30** | **24** | **21** | **19** |
| **1400-1600** | **8** | **24** | **25** | **29** | **28** | **27** | **22** | **22** |
| **1600-1800** | **9** | **22** | **30** | **36** | **24** | **28** | **26** | **19** |
| **1800-2000** | **10** | **20** | **25** | **26** | **23** | **23** | **27** | **17** |
| **2000-2200** | **11** | **18** | **20** | **23** | **19** | **21** | **22** | **13** |
| **2200-2400** | **12** | **11** | **15** | **21** | **25** | **32** | **28** | **13** |

**Table 1. Average calls for each time period in January 2012.**

It is assumed that the average number of calls in a month will be a sufficient predictor of the calls that will occur in the weeks immediately following the time the data was collected. For this model it will be assumed that the schedule being created is for the week of February 6 to 12th, 2012.

The first step of creating the model was to identify variables and indices. The indices used in this model will be

Variables were needed for the total number of officers available, the number of officers needed each hour, the officers starting each shift, and others as listed below.

|  |  |
| --- | --- |
|  | Total officers in district |
|  | Minimum officers during any hour |
|  | Number of officers per car (per call) |
|  | Officers needed on day j at 2-hour period k |
|  | Officers starting on shift i on day j |
|  | Surplus of officers on day j at 2-hour period k |
|  | Shortage of officers on day j at 2-hour period k |
|  | Maximum shortage at any hour |

Each officer related variable was constrained to be an integer.

The objective of the model is to minimize the total shortages and surpluses of officers during a week. This objective addresses both cost and customer service concerns. A secondary object was proposed to minimize the largest hourly shortage. The objective function is defined using the formula

This objective is subject to constraints that represent the number of officers set to work each shift, the maximum number of officers that can start work, and the minimum number of officers that should be available at any hour. These constraints are summarized below.

Max Shortage:

Minimum Officers (each hour):

Non Negative:

Non Negative:

Non Negative:

Non Negative:

These constraints are modified to incorporate the correct summation ranges for each hour given the shift starting times, the hours worked, and tour lengths. The full model definitions for each case studied can be found attached in the appendix.

These constraints force a few interesting characteristics of the variables. First, the values of S and L are set to be always positive and are therefore exclusive in each equation. For any hour, only one S or L can be non-zero. Second, the maximum shortage *y* is always set to the largest S found across any hour or shift. These characteristics allow for the number of officers starting each shift to be optimized to minimize the total shortages and surpluses.

# Analysis

The three models were solved using the Gurobi solver provided by AMPL student edition using the command script listed in the Appendix. Initial results for each model using variables of 100 total officers and one officer per car are listed in Table 2.

|  |  |  |  |
| --- | --- | --- | --- |
|  | **5/10 3 shifts** | **4/10 3 shifts** | **4/10 5 shifts** |
| Sum of Shortages and Surpluses | 343 | 469 | 339 |
| Maximum Shortage | 13 | 27 | 9 |
| Total Officers | 83 | 77 | 76 |

**Table 2. Results of Model with one officer per car, 100 total officers.**

These numbers represent the optimum solutions found for each case. Scheduling police officers for the district on a 5 day week and 8 hours per day schedule will result in a total sum of shortages and surpluses of 343 with 83 officers scheduled to work during the week. The schedule of officers starting work is calculated using the formula:

The results of this formula are shown in Table 3.

|  |  |  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- | --- | --- |
| **Shift** | **Time** | **Mon** | **Tue** | **Wed** | **Thu** | **Fri** | **Sat** | **Sun** |
| **3** | **0000-0200** | 13 | 8 | 10 | 12 | 17 | 20 | 20 |
| **3** | **0200-0400** | 13 | 8 | 10 | 12 | 17 | 20 | 20 |
| **3** | **0400-0600** | 13 | 8 | 10 | 12 | 17 | 20 | 20 |
| **1** | **0600-0800** | 19 | 22 | 29 | 20 | 20 | 19 | 16 |
| **1** | **0800-1000** | 19 | 22 | 29 | 20 | 20 | 19 | 16 |
| **1** | **1000-1200** | 19 | 22 | 29 | 20 | 20 | 19 | 16 |
| **1** | **1200-1400** | 19 | 22 | 29 | 20 | 20 | 19 | 16 |
| **2** | **1400-1600** | 22 | 25 | 29 | 24 | 27 | 24 | 19 |
| **2** | **1600-1800** | 22 | 25 | 29 | 24 | 27 | 24 | 19 |
| **2** | **1800-2000** | 22 | 25 | 29 | 24 | 27 | 24 | 19 |
| **2** | **2000-2200** | 22 | 25 | 29 | 24 | 27 | 24 | 19 |
| **3** | **2200-2400** | 8 | 10 | 12 | 17 | 20 | 20 | 13 |

**Table 3. Officers working each time period using the 5/8 schedule.**

This is the baseline solution to the problem and is assumed to be the current operating state for the Sacramento police department.

The second case of the model to be run is a 4 day per week, 10 hour shift schedule with three shift starting times. The department has considered this schedule before and found it to be wasteful and ineffective. The results from the model verify the previous findings. The optimum solution for a 4day, 10 hour schedule results in a total sum of shortages and surpluses of 469 with 77 officers scheduled to work during the week. The maximum forecasted shortage is found to be 27 officers from 0000 to 0200 on Sunday. The 4/10 schedule is found to be inferior to the original schedule despite the reduction of 6 officers from the total headcount. The optimal schedule will allow for a much larger shortage and a larger total of hourly shortages and surpluses.

The Sacramento police union has also suggested a 4/10 schedule with five shift starting times per day. A model was constructed using 4 a.m., 8 a.m., 12 p.m., 4 p.m., and 8 p.m. as the starting times each day. This model results in a total sum of shortages and surpluses of 339 with 76 officers scheduled to work during the week. The maximum shortage of 9 officers is forecasted to occur six times during the week, but is about as common as in other scenarios. This is significant improvement from the 5/8 schedule. The new schedule will allow the police department to remove 7 officers from patrol duty and will provide better response times and service levels than the 5/8 or 4/10 3 shift schedules.

The 4/10 schedule with five shifts is found to be preferable with an unlimited number of available officers to be assigned. The models can also be run using a set number of available officers. Analysis was performed to find the point at which the 5/8 schedule is preferred to the 4/10 schedule. The currently used 5/8 schedule should be preferred to the 4/10 schedule if the district has less than 53 officers to assign during the week. These results can be seen in Table 4.

|  |  |  |  |
| --- | --- | --- | --- |
|  | **5/10 3 shifts** | **4/10 3 shifts** | **4/10 5 shifts** |
| Sum of Shortages and Surpluses | 543 | 573 | 561 |
| Maximum Shortage | 26 | 27 | 15 |

**Table 4. Results with 52 officers.**

The police department can also investigate different shift starting times. The previous schedule would have several hours where there would only be one shift of officers covering the hours. Rearranging the shifts to ensure that each hour has two shifts of officers covering the time should show some improvement. Starting times of 0000, 0400, 0800, 1400, and 1800 ensure coverage by a minimum of two shifts. The results of this model (410\_5shift\_r.mod) are given in Table 5.

|  |  |  |
| --- | --- | --- |
|  | **4/10 5 shifts** | **4/10 5 New** |
| Sum of Shortages and Surpluses | 339 | 235 |
| Maximum Shortage | 9 | 12 |
| Total Officers | 76 | 76 |

**Table 5. Results of Model with new starting times.**

This table shows that by rearranging the officers to work the new shift starting times and maximizing cross coverage, the department can greatly reduce the sum of shortages and surpluses with the same staffing. The main risk associated is that there is a small rise in the potential maximum shortage of officers by 3 officers.

The solutions given above can be used to make decisions on staffing levels in the department. Each solution shows the number of officers needed to reach the optimal schedule. If the department has fewer officers they can assess the risk of allowing a smaller force by changing the number of total officers in the data file. They can also add additional officers to simulate adding temporary staffing or borrowing officers from another district. A good measure of the risk associated with the reduced schedule is the maximum shortage number. Also, any schedule which requires less than the total number of officers indicates a surplus of officers that can be assigned to new tasks, loaned to another department, or removed from the district. This will allow for the chief of police to improve efficiency by restructuring the officers into different districts and assigned areas.

There are many additional factors that could be investigated to improve the decision making capability of the models. The models were written with the ability to investigate the effect of requiring more than one officer per call. The model assumes that if more than one officer is required per car that every car will have the same number of officers. This will effectively multiply the number of officers needed for each time period by the new number in each car. With a new number of two officers per car the results show that the 4/10 five shift schedule is still the preferable option, but will be more costly and less effective than one officer per car. This may be required, however, for officer safety.

# Conclusion

The application of linear programming concepts to a personnel scheduling problem can yield significant savings and better understanding of needs. The police scheduling problem models have shown that the Sacramento police department should consider switching to a 4 day, 10 hour, 5 shift schedules with starting times set to maximize cross coverage (ex. 0000, 0400, 0800, 1400, 1800 starting times) to increase the customer service and decrease the costs associated with patrol officers. The change in schedule will reduce necessary headcount by seven officers and decrease the maximum forecasted shortage of officers from 13 missed calls to 9.

The Sacramento police department could benefit greatly from expanding the scope of this study to include new options. The models could be appended to allow for inclusion of shared first responder personnel with the fire department and EMT services. Also, the models could be used to predict which shifts will have large shortages or surpluses so the management can schedule temporary staffing to cover shortages or schedule value added alternative projects for on call surplus officers. If these decisions are made in advance the city will find that their officers are better utilized.

A graphical interface and decision support system would make the system easy to use and efficient. The solutions from the AMPL models are returned in less than 5 seconds with the current parameters. This allows for many alternative solutions to be provided quickly. If a GUI and decision support system were added to the work displayed here the management could test scheduling changes, alternative schedules, and change forecasting data quickly. Also, the system could be made to automatically pull and enter historical data for any time period in the CAD database.

# Appendix

## Model Files



## Output Files

## 

## Fully Expanded Models

See attached files:



## Model Definitions

**Case 1 – 5/8 schedule starting at 6am, 2pm, 10pm AMPL Code:**

###############################################

# Justin Bearden #

# IEE 574 - Summer 2012 #

# 5/8 Schedule Police Department #

###############################################

param officers; # Total officers in district

param min\_officers; # Minimum officers during any hour

param officers\_per\_car; # Number of officers per car (per call)

param D{j in 1..7, k in 1..12}; # Officers needed on day j at 2-hour period k (from data)

# i = 1..3 = shifts

# j = 1..7 = days

# k = 1..12 = 2 hour time units

var X{i in 1..3, j in 1..7} integer; # Officers starting on shift i on day j

var L{j in 1..7, k in 1..12} integer; # Surplus of officers on day j at hour k

var S{j in 1..7, k in 1..12} integer; # Shortage of officers on day j at hour k

var y integer; # Maximum shortage or surplus

# Objective statement

minimize total\_diff: sum{j in 1..7, k in 1..12} S[j,k] + sum{j in 1..7, k in 1..12} L[j,k];

minimize max\_shortage: y;

minimize total\_diff\_and\_max\_shortage: sum{j in 1..7, k in 1..12} S[j,k] + sum{j in 1..7, k in 1..12} L[j,k] + y;

# Constraints

subject to max\_y\_shortage{j in 1..7, k in 1..12}: y >= S[j,k]; # y is maximum shortage over any time

subject to total\_officers: sum{i in 1..3, j in 1..7} X[i,j] <= officers; # officers starting <= total officers

# Hours 1 to 3 (Shift 3)

subject to hour1to3\_day1to5{j in 1..5,k in 1..3}: sum{m in 1..j-1} X[3,m] + sum{m in j+2..7} X[3,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

subject to hour1to3\_day6to7{j in 6..7,k in 1..3}: sum{m in j-5..j-1} X[3,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

# Hours 4 to 7 (Shift 1)

subject to hour4to7\_day1to4{j in 1..4,k in 4..7}: sum{m in j+3..7} X[1,m] + sum{m in 1..j} X[1,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

subject to hour4to7\_day5to7{j in 5..7,k in 4..7}: sum{m in j-4..j} X[1,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

# Hours 8 to 11 (Shift 2)

subject to hour8to11\_day1to4{j in 1..4,k in 8..11}: sum{m in j+3..7} X[2,m] + sum{m in 1..j} X[2,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

subject to hour8to11\_day5to7{j in 5..7,k in 8..11}: sum{m in j-4..j} X[2,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

# Hour 12 (Shift 3)

subject to hour12\_day1to4{j in 1..4,k in 12..12}: sum{m in j+3..7} X[3,m] + sum{m in 1..j} X[3,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

subject to hour12\_day5to7{j in 5..7,k in 12..12}: sum{m in j-4..j} X[3,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

# Minimum Officers

subject to minofficer\_01\_1{j in 1..5,k in 1..3}: sum{m in 1..j-1} X[3,m] + sum{m in j+2..7} X[3,m] >= min\_officers;

subject to minofficer\_01\_2{j in 6..7,k in 1..3}: sum{m in j-5..j-1} X[3,m] >= min\_officers;

subject to minofficer\_04\_1{j in 1..4,k in 4..7}: sum{m in j+3..7} X[1,m] + sum{m in 1..j} X[1,m] >= min\_officers;

subject to minofficer\_04\_2{j in 5..7,k in 4..7}: sum{m in j-4..j} X[1,m] >= min\_officers;

subject to minofficer\_08\_1{j in 1..4,k in 8..11}: sum{m in j+3..7} X[2,m] + sum{m in 1..j} X[2,m] >= min\_officers;

subject to minofficer\_08\_2{j in 5..7,k in 8..11}: sum{m in j-4..j} X[2,m] >= min\_officers;

subject to minofficer\_12\_1{j in 1..4,k in 12..12}: sum{m in j+3..7} X[3,m] + sum{m in 1..j} X[3,m] >= min\_officers;

subject to minofficer\_12\_2{j in 5..7,k in 12..12}: sum{m in j-4..j} X[3,m] >= min\_officers;

# Non-negative constraints

subject to positive\_y: y >= 0;

subject to positive\_X{i in 1..3, j in 1..7}: X[i,j] >= 0;

subject to positive\_L{j in 1..7, k in 1..12}: L[j,k] >= 0;

subject to positive\_S{j in 1..7, k in 1..12}: S[j,k] >= 0;

**Case 2 – 4/10 schedule starting at 6am, 2pm, 10pm AMPL Code:**

###############################################

# Justin Bearden #

# IEE 574 - Summer 2012 #

# 4/10 Schedule Police Department #

###############################################

param officers; # Total officers in district

param min\_officers; # Minimum officers during any hour

param officers\_per\_car; # Number of officers per car (per call)

param D{j in 1..7, k in 1..12}; # Officers needed on day j at 2-hour period k (from data)

# i = 1..3 = shifts

# j = 1..7 = days

# k = 1..12 = 2 hour time units

var X{i in 1..3, j in 1..7} integer; # Officers starting on shift i on day j

var L{j in 1..7, k in 1..12} integer; # Surplus of officers on day j at hour k

var S{j in 1..7, k in 1..12} integer; # Shortage of officers on day j at hour k

var y integer; # Maximum shortage or surplus

# Objective statement

minimize total\_diff: sum{j in 1..7, k in 1..12} S[j,k] + sum{j in 1..7, k in 1..12} L[j,k];

minimize max\_shortage: y;

minimize total\_diff\_and\_max\_shortage: sum{j in 1..7, k in 1..12} S[j,k] + sum{j in 1..7, k in 1..12} L[j,k] + y;

# Constraints

subject to max\_y\_shortage{j in 1..7, k in 1..12}: y >= S[j,k]; # y is maximum shortage over any time

subject to total\_officers: sum{i in 1..3, j in 1..7} X[i,j] <= officers; # officers starting <= total officers

# Hours 1 to 3 (Shift 3)

subject to hour1to3\_day1to4{j in 1..4,k in 1..3}: sum{m in 1..j-1} X[3,m] + sum{m in j+3..7} X[3,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

subject to hour1to3\_day5to7{j in 5..7,k in 1..3}: sum{m in j-4..j-1} X[3,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

# Hour 4 (Shift 3 and 1)

subject to hour4\_day1to3{j in 1..3,k in 4..4}: sum{m in 1..j-1} X[3,m] + sum{m in j+3..7} X[3,m] + sum{m in j+4..7} X[1,m] + sum{m in 1..j} X[1,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

subject to hour4\_day4{j in 4..4,k in 4..4}: sum{m in 1..j-1} X[3,m] + sum{m in j+3..7} X[3,m] + sum{m in j-3..j} X[1,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

subject to hour4\_day7{j in 5..7,k in 4..4}: sum{m in j-4..j-1} X[3,m] + sum{m in j-3..j} X[1,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

# Hours 5 to 7 (Shift 1)

subject to hour5to7\_day1to3{j in 1..3,k in 5..7}: sum{m in j+4..7} X[1,m] + sum{m in 1..j} X[1,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

subject to hour5to7\_day4to7{j in 4..7,k in 5..7}: sum{m in j-3..j} X[1,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

# Hour 8 (Shift 1 and 2)

subject to hour8\_day1to3{j in 1..3,k in 8..8}: sum{m in j+4..7} X[1,m] + sum{m in 1..j} X[1,m] + sum{m in j+4..7} X[2,m] + sum{m in 1..j} X[2,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

subject to hour8\_day4to7{j in 4..7,k in 8..8}: sum{m in j-3..j} X[1,m] + sum{m in j-3..j} X[2,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

# Hours 9 to 11 (Shift 2)

subject to hour9to11\_day1to3{j in 1..3,k in 9..11}: sum{m in j+4..7} X[2,m] + sum{m in 1..j} X[2,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

subject to hour9to11\_day4to7{j in 4..7,k in 9..11}: sum{m in j-3..j} X[2,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

# Hour 12 (Shift 2 and 3)

subject to hour12\_day1to3{j in 1..3,k in 12..12}: sum{m in j+4..7} X[2,m] + sum{m in 1..j} X[2,m] + sum{m in j+4..7} X[3,m] + sum{m in 1..j} X[3,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

subject to hour12\_day4to7{j in 4..7,k in 12..12}: sum{m in j-3..j} X[2,m] + sum{m in j-3..j} X[3,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

# Minimum Officers

subject to minofficer\_01\_1{j in 1..4,k in 1..3}: sum{m in 1..j-1} X[3,m] + sum{m in j+3..7} X[3,m] >= min\_officers;

subject to minofficer\_01\_2{j in 5..7,k in 1..3}: sum{m in j-4..j-1} X[3,m] >= min\_officers;

subject to minofficer\_04\_1{j in 1..3,k in 4..4}: sum{m in 1..j-1} X[3,m] + sum{m in j+3..7} X[3,m] + sum{m in j+4..7} X[1,m] + sum{m in 1..j} X[1,m] >= min\_officers;

subject to minofficer\_04\_2{j in 4..4,k in 4..4}: sum{m in 1..j-1} X[3,m] + sum{m in j+3..7} X[3,m] + sum{m in j-3..j} X[1,m] >= min\_officers;

subject to minofficer\_04\_3{j in 5..7,k in 4..4}: sum{m in j-4..j-1} X[3,m] + sum{m in j-3..j} X[1,m] >= min\_officers;

subject to minofficer\_05\_1{j in 1..3,k in 5..7}: sum{m in j+4..7} X[1,m] + sum{m in 1..j} X[1,m] >= min\_officers;

subject to minofficer\_05\_2{j in 4..7,k in 5..7}: sum{m in j-3..j} X[1,m] >= min\_officers;

subject to minofficer\_08\_1{j in 1..3,k in 8..8}: sum{m in j+4..7} X[1,m] + sum{m in 1..j} X[1,m] + sum{m in j+4..7} X[2,m] + sum{m in 1..j} X[2,m] >= min\_officers;

subject to minofficer\_08\_2{j in 4..7,k in 8..8}: sum{m in j-3..j} X[1,m] + sum{m in j-3..j} X[2,m] >= min\_officers;

subject to minofficer\_09\_1{j in 1..3,k in 9..11}: sum{m in j+4..7} X[2,m] + sum{m in 1..j} X[2,m] >= min\_officers;

subject to minofficer\_09\_2{j in 4..7,k in 9..11}: sum{m in j-3..j} X[2,m] >= min\_officers;

subject to minofficer\_12\_1{j in 1..3,k in 12..12}: sum{m in j+4..7} X[2,m] + sum{m in 1..j} X[2,m] + sum{m in j+4..7} X[3,m] + sum{m in 1..j} X[3,m] >= min\_officers;

subject to minofficer\_12\_2{j in 4..7,k in 12..12}: sum{m in j-3..j} X[2,m] + sum{m in j-3..j} X[3,m] >= min\_officers;

# Non-negative constraints

subject to positive\_y: y >= 0;

subject to positive\_X{i in 1..3, j in 1..7}: X[i,j] >= 0;

subject to positive\_L{j in 1..7, k in 1..12}: L[j,k] >= 0;

subject to positive\_S{j in 1..7, k in 1..12}: S[j,k] >= 0;

**Case 3 – 4/10 schedule starting at 4am, 8am, 12pm, 4pm, 8pm AMPL Code:**

###############################################

# Justin Bearden #

# IEE 574 - Summer 2012 #

# 4/10 - 5 shifts Schedule Police Department #

###############################################

param officers; # Total officers in district

param min\_officers; # Minimum officers during any hour

param officers\_per\_car; # Number of officers per car (per call)

param D{j in 1..7, k in 1..12}; # Officers needed on day j at 2-hour period k (from data)

# i = 1..5 = shifts

# j = 1..7 = days

# k = 1..12 = 2 hour time units

var X{i in 1..5, j in 1..7} integer; # Officers starting on shift i on day j

var L{j in 1..7, k in 1..12} integer; # Surplus of officers on day j at hour k

var S{j in 1..7, k in 1..12} integer; # Shortage of officers on day j at hour k

var y integer; # Maximum shortage or surplus

# Objective statement

minimize total\_diff: sum{j in 1..7, k in 1..12} S[j,k] + sum{j in 1..7, k in 1..12} L[j,k];

minimize max\_shortage: y;

minimize total\_diff\_and\_max\_shortage: (sum{j in 1..7, k in 1..12} S[j,k]) + sum{j in 1..7, k in 1..12} L[j,k] + y;

# Constraints

subject to max\_y\_shortage{j in 1..7, k in 1..12}: y >= S[j,k]; # y is maximum shortage over any time

subject to total\_officers: sum{i in 1..5, j in 1..7} X[i,j] <= officers; # officers starting <= total officers

# Hour 1 (Shift 4, 5)

subject to hour1\_day1to4{j in 1..4,k in 1..1}: sum{m in 1..j-1} X[4,m] + sum{m in j+3..7} X[4,m] + sum{m in 1..j-1} X[5,m] + sum{m in j+3..7} X[5,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

subject to hour1\_day5to7{j in 5..7,k in 1..1}: sum{m in j-4..j-1} X[4,m] + sum{m in j-4..j-1} X[5,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

# Hour 2 (Shift 5)

subject to hour2\_day1to4{j in 1..4,k in 2..2}: sum{m in 1..j-1} X[5,m] + sum{m in j+3..7} X[5,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

subject to hour2\_day5to7{j in 5..7,k in 2..2}: sum{m in j-4..j-1} X[5,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

# Hour 3 (Shift 1, 5)

subject to hour3\_day1to3{j in 1..3,k in 3..3}: sum{m in j+4..7} X[1,m] + sum{m in 1..j} X[1,m] + sum{m in 1..j-1} X[5,m] + sum{m in j+3..7} X[5,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

subject to hour3\_day4to4{j in 4..4,k in 3..3}: sum{m in j-3..j} X[1,m] + sum{m in 1..j-1} X[5,m] + sum{m in j+3..7} X[5,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

subject to hour3\_day5to7{j in 5..7,k in 3..3}: sum{m in j-3..j} X[1,m] + sum{m in j-4..j-1} X[5,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

# Hour 4 (Shift 1)

subject to hour4\_day1to3{j in 1..3,k in 4..4}: sum{m in j+4..7} X[1,m] + sum{m in 1..j} X[1,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

subject to hour4\_day4to7{j in 4..7,k in 4..4}: sum{m in j-3..j} X[1,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

# Hours 5 to 6 (Shift 1, 2)

subject to hour5to6\_day1to3{j in 1..3,k in 5..6}: sum{m in j+4..7} X[1,m] + sum{m in 1..j} X[1,m] + sum{m in j+4..7} X[2,m] + sum{m in 1..j} X[2,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

subject to hour5to6\_day4to7{j in 4..7,k in 5..6}: sum{m in j-3..j} X[1,m] + sum{m in j-3..j} X[2,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

# Hour 7 (Shift 1, 2, 3)

subject to hour7\_day1to3{j in 1..3,k in 7..7}: sum{m in j+4..7} X[1,m] + sum{m in 1..j} X[1,m] + sum{m in j+4..7} X[2,m] + sum{m in 1..j} X[2,m] + sum{m in j+4..7} X[3,m] + sum{m in 1..j} X[3,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

subject to hour7\_day4to7{j in 4..7,k in 7..7}: sum{m in j-3..j} X[1,m] + sum{m in j-3..j} X[2,m] + sum{m in j-3..j} X[3,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

# Hour 8 (Shift 2, 3)

subject to hour8\_day1to3{j in 1..3,k in 8..8}: sum{m in j+4..7} X[2,m] + sum{m in 1..j} X[2,m] + sum{m in j+4..7} X[3,m] + sum{m in 1..j} X[3,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

subject to hour8\_day4to7{j in 4..7,k in 8..8}: sum{m in j-3..j} X[2,m] + sum{m in j-3..j} X[3,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

# Hour 9 (Shift 2, 3, 4)

subject to hour9\_day1to3{j in 1..3,k in 9..9}: sum{m in j+4..7} X[2,m] + sum{m in 1..j} X[2,m] + sum{m in j+4..7} X[3,m] + sum{m in 1..j} X[3,m] + sum{m in j+4..7} X[4,m] + sum{m in 1..j} X[4,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

subject to hour9\_day4to7{j in 4..7,k in 9..9}: sum{m in j-3..j} X[2,m] + sum{m in j-3..j} X[3,m] + sum{m in j-3..j} X[4,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

# Hour 10 (Shift 3, 4)

subject to hour10\_day1to3{j in 1..3,k in 10..10}: sum{m in j+4..7} X[3,m] + sum{m in 1..j} X[3,m] + sum{m in j+4..7} X[4,m] + sum{m in 1..j} X[4,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

subject to hour10\_day4to7{j in 4..7,k in 10..10}: sum{m in j-3..j} X[3,m] + sum{m in j-3..j} X[4,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

# Hour 11 (Shift 3, 4, 5)

subject to hour11\_day1to3{j in 1..3,k in 11..11}: sum{m in j+4..7} X[3,m] + sum{m in 1..j} X[3,m] + sum{m in j+4..7} X[4,m] + sum{m in 1..j} X[4,m] + sum{m in j+4..7} X[5,m] + sum{m in 1..j} X[5,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

subject to hour11\_day4to7{j in 4..7,k in 11..11}: sum{m in j-3..j} X[3,m] + sum{m in j-3..j} X[4,m] + sum{m in j-3..j} X[5,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

# Hour 12 (Shift 4, 5)

subject to hour12\_day1to3{j in 1..3,k in 12..12}: sum{m in j+4..7} X[4,m] + sum{m in 1..j} X[4,m] + sum{m in j+4..7} X[5,m] + sum{m in 1..j} X[5,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

subject to hour12\_day4to7{j in 4..7,k in 12..12}: sum{m in j-3..j} X[4,m] + sum{m in j-3..j} X[5,m] + S[j,k] - L[j,k] = D[j,k] \* officers\_per\_car;

# Minimum Officers

subject to min\_officer\_01\_1{j in 1..4,k in 1..1}: sum{m in 1..j-1} X[4,m] + sum{m in j+3..7} X[4,m] + sum{m in 1..j-1} X[5,m] + sum{m in j+3..7} X[5,m] >= min\_officers;

subject to min\_officer\_01\_2{j in 5..7,k in 1..1}: sum{m in j-4..j-1} X[4,m] + sum{m in j-4..j-1} X[5,m] >= min\_officers;

subject to min\_officer\_02\_1{j in 1..4,k in 2..2}: sum{m in 1..j-1} X[5,m] + sum{m in j+3..7} X[5,m] >= min\_officers;

subject to min\_officer\_02\_2{j in 5..7,k in 2..2}: sum{m in j-4..j-1} X[5,m] >= min\_officers;

subject to min\_officer\_03\_1{j in 1..3,k in 3..3}: sum{m in j+4..7} X[1,m] + sum{m in 1..j} X[1,m] + sum{m in 1..j-1} X[5,m] + sum{m in j+3..7} X[5,m] >= min\_officers;

subject to min\_officer\_03\_2{j in 4..4,k in 3..3}: sum{m in j-3..j} X[1,m] + sum{m in 1..j-1} X[5,m] + sum{m in j+3..7} X[5,m] >= min\_officers;

subject to min\_officer\_03\_3{j in 5..7,k in 3..3}: sum{m in j-3..j} X[1,m] + sum{m in j-4..j-1} X[5,m] >= min\_officers;

subject to min\_officer\_04\_1{j in 1..3,k in 4..4}: sum{m in j+4..7} X[1,m] + sum{m in 1..j} X[1,m] >= min\_officers;

subject to min\_officer\_04\_2{j in 4..7,k in 4..4}: sum{m in j-3..j} X[1,m] >= min\_officers;

subject to min\_officer\_05\_1{j in 1..3,k in 5..6}: sum{m in j+4..7} X[1,m] + sum{m in 1..j} X[1,m] + sum{m in j+4..7} X[2,m] + sum{m in 1..j} X[2,m] >= min\_officers;

subject to min\_officer\_05\_2{j in 4..7,k in 5..6}: sum{m in j-3..j} X[1,m] + sum{m in j-3..j} X[2,m] >= min\_officers;

subject to min\_officer\_07\_1{j in 1..3,k in 7..7}: sum{m in j+4..7} X[1,m] + sum{m in 1..j} X[1,m] + sum{m in j+4..7} X[2,m] + sum{m in 1..j} X[2,m] + sum{m in j+4..7} X[3,m] + sum{m in 1..j} X[3,m] >= min\_officers;

subject to min\_officer\_07\_2{j in 4..7,k in 7..7}: sum{m in j-3..j} X[1,m] + sum{m in j-3..j} X[2,m] + sum{m in j-3..j} X[3,m] >= min\_officers;

subject to min\_officer\_08\_1{j in 1..3,k in 8..8}: sum{m in j+4..7} X[2,m] + sum{m in 1..j} X[2,m] + sum{m in j+4..7} X[3,m] + sum{m in 1..j} X[3,m] >= min\_officers;

subject to min\_officer\_08\_2{j in 4..7,k in 8..8}: sum{m in j-3..j} X[2,m] + sum{m in j-3..j} X[3,m] >= min\_officers;

subject to min\_officer\_09\_1{j in 1..3,k in 9..9}: sum{m in j+4..7} X[2,m] + sum{m in 1..j} X[2,m] + sum{m in j+4..7} X[3,m] + sum{m in 1..j} X[3,m] + sum{m in j+4..7} X[4,m] + sum{m in 1..j} X[4,m] >= min\_officers;

subject to min\_officer\_09\_2{j in 4..7,k in 9..9}: sum{m in j-3..j} X[2,m] + sum{m in j-3..j} X[3,m] + sum{m in j-3..j} X[4,m] >= min\_officers;

subject to min\_officer\_10\_1{j in 1..3,k in 10..10}: sum{m in j+4..7} X[3,m] + sum{m in 1..j} X[3,m] + sum{m in j+4..7} X[4,m] + sum{m in 1..j} X[4,m] >= min\_officers;

subject to min\_officer\_10\_2{j in 4..7,k in 10..10}: sum{m in j-3..j} X[3,m] + sum{m in j-3..j} X[4,m] >= min\_officers;

subject to min\_officer\_11\_1{j in 1..3,k in 11..11}: sum{m in j+4..7} X[3,m] + sum{m in 1..j} X[3,m] + sum{m in j+4..7} X[4,m] + sum{m in 1..j} X[4,m] + sum{m in j+4..7} X[5,m] + sum{m in 1..j} X[5,m] >= min\_officers;

subject to min\_officer\_11\_2{j in 4..7,k in 11..11}: sum{m in j-3..j} X[3,m] + sum{m in j-3..j} X[4,m] + sum{m in j-3..j} X[5,m] >= min\_officers;

subject to min\_officer\_12\_1{j in 1..3,k in 12..12}: sum{m in j+4..7} X[4,m] + sum{m in 1..j} X[4,m] + sum{m in j+4..7} X[5,m] + sum{m in 1..j} X[5,m] >= min\_officers;

subject to min\_officer\_12\_2{j in 4..7,k in 12..12}: sum{m in j-3..j} X[4,m] + sum{m in j-3..j} X[5,m] >= min\_officers;

# Non-negative constraints

subject to positive\_y: y >= 0;

subject to positive\_X{i in 1..5, j in 1..7}: X[i,j] >= 0;

subject to positive\_L{j in 1..7, k in 1..12}: L[j,k] >= 0;

subject to positive\_S{j in 1..7, k in 1..12}: S[j,k] >= 0;

## Data Files

**Data File AMPL Code:**

##DATA FILE

param officers := 100;

param min\_officers := 3;

param officers\_per\_car := 1;

# Officers needed at each hour

param D:

1 2 3 4 5 6 7 8 9 10 11 12 :=

1 14 8 5 14 14 19 21 24 22 20 18 11

2 8 6 3 13 21 23 25 25 30 25 20 15

3 9 8 4 14 26 31 30 29 36 26 23 21

4 14 8 4 13 18 21 30 28 24 23 19 25

5 17 10 4 14 20 23 24 27 28 23 21 32

6 25 14 6 9 17 19 21 22 26 27 22 28

7 33 21 6 8 15 16 19 22 19 17 13 13

**Script to run all cases and export files:**

# 5/8 Model

reset;

model mod/cs1\_JB\_58.mod;

data mod/cs1\_JB\_data.dat;

option solver gurobi;

objective total\_diff\_and\_max\_shortage;

solve;

print 'Run 1: 5/8 Schedule, 6am 2pm 10pm shifts' >mod/out/58\_schedule.out;

print '' >mod/out/58\_schedule.out;

print 'Objectives:' >mod/out/58\_schedule.out;

display total\_diff, max\_shortage, total\_diff\_and\_max\_shortage >mod/out/58\_schedule.out;

print 'Total Officers:' >mod/out/58\_schedule.out;

display sum{i in 1..3, j in 1..7} X[i,j] >mod/out/58\_schedule.out;

print 'Total Officers Working (each day):' >mod/out/58\_schedule.out;

display {j in 1..7, k in 1..12}(D[j,k]+L[j,k]-S[j,k]) >mod/out/58\_schedule.out;

print 'Schedule:' >mod/out/58\_schedule.out;

display X >mod/out/58\_schedule.out;

print 'Shortages:' >mod/out/58\_schedule.out;

display S >mod/out/58\_schedule.out;

print 'Surpluses:' >mod/out/58\_schedule.out;

display L >mod/out/58\_schedule.out;

print 'Officers Needed:' >mod/out/58\_schedule.out;

display D >mod/out/58\_schedule.out;

close mod/out/58\_schedule.out;

print 'Full Model Definition: 5/8 Schedule, 6am 2pm 10pm shifts' >mod/out/58\_full\_model.out;

expand >mod/out/58\_full\_model.out;

close mod/out/out/58\_full\_model.out;

# 4/10 Model

reset;

model mod/cs1\_JB\_410.mod;

data mod/cs1\_JB\_data.dat;

option solver gurobi;

objective total\_diff\_and\_max\_shortage;

solve;

print 'Run 2: 4/10 Schedule, 6am 2pm 10pm shifts' >mod/out/410\_schedule.out;

print '' >mod/out/410\_schedule.out;

print 'Objectives:' >mod/out/410\_schedule.out;

display total\_diff, max\_shortage, total\_diff\_and\_max\_shortage >mod/out/410\_schedule.out;

print 'Total Officers:' >mod/out/410\_schedule.out;

display sum{i in 1..3, j in 1..7} X[i,j] >mod/out/410\_schedule.out;

print 'Total Officers Working (each day):' >mod/out/410\_schedule.out;

display {j in 1..7, k in 1..12}(D[j,k]+L[j,k]-S[j,k]) >mod/out/410\_schedule.out;

print 'Schedule:' >mod/out/410\_schedule.out;

display X >mod/out/410\_schedule.out;

print 'Shortages:' >mod/out/410\_schedule.out;

display S >mod/out/410\_schedule.out;

print 'Surpluses:' >mod/out/410\_schedule.out;

display L >mod/out/410\_schedule.out;

print 'Officers Needed:' >mod/out/410\_schedule.out;

display D >mod/out/410\_schedule.out;

close mod/out/410\_schedule.out;

print 'Full Model Definition: 4/10 Schedule, 6am 2pm 10pm shifts' >mod/out/410\_full\_model.out;

expand >mod/out/410\_full\_model.out;

close mod/out/410\_full\_model.out;

# 4/10 Model with 5 shifts

reset;

model mod/cs1\_JB\_410\_5shift.mod;

data mod/cs1\_JB\_data.dat;

option solver gurobi;

objective total\_diff\_and\_max\_shortage;

solve;

print 'Run 3: 4/10 Schedule, 4am 8am 12 pm 2pm 4pm shifts' >mod/out/410\_5shift\_schedule.out;

print '' >mod/out/410\_5shift\_schedule.out;

print 'Objectives:' >mod/out/410\_5shift\_schedule.out;

display total\_diff, max\_shortage, total\_diff\_and\_max\_shortage >mod/out/410\_5shift\_schedule.out;

print 'Total Officers:' >mod/out/410\_5shift\_schedule.out;

display sum{i in 1..5, j in 1..7} X[i,j] >mod/out/410\_5shift\_schedule.out;

print 'Total Officers Working (each day):' >mod/out/410\_5shift\_schedule.out;

display {j in 1..7, k in 1..12}(D[j,k]+L[j,k]-S[j,k]) >mod/out/410\_5shift\_schedule.out;

print 'Schedule:' >mod/out/410\_5shift\_schedule.out;

display X >mod/out/410\_5shift\_schedule.out;

print 'Shortages:' >mod/out/410\_5shift\_schedule.out;

display S >mod/out/410\_5shift\_schedule.out;

print 'Surpluses:' >mod/out/410\_5shift\_schedule.out;

display L >mod/out/410\_5shift\_schedule.out;

print 'Officers Needed:' >mod/out/410\_5shift\_schedule.out;

display D >mod/out/410\_5shift\_schedule.out;

close mod/out/410\_5shift\_schedule.out;

print 'Full Model Definition: 4/10 Schedule, 4am 8am 12pm 4pm 8pm shifts' >mod/out/410\_5shift\_full\_model.out;

expand >mod/out/410\_5shift\_full\_model.out;

close mod/out/410\_5shift\_full\_model.out;